F(x):=

"USUM berechnet die Summe einer Ann„herung durch eingeschriebene"

"Rechtecke einer vordefinierten Funktion F(x) . a ist der"

"Beginn des Intervalls, b das Ende, n die Zahl der Rechtecke."

USUM(a,b,n):=SUM(F(a+k*(b-a)/n)*(b-a)/n,k,0,n-1)

"OSum n„hert wie USum durch obere Rechtecke"

OSUM(a,b,n):=SUM(F(a+k*(b-a)/n)*(b-a)/n,k,1,n)

"DIFSUM(a,b,n) berechnet die Differenz aus Ober u. Untersumme"

"im Intervall [a,b] mit Feinheit n"

DIFSUM(a,b,n):=OSUM(a,b,n)-USUM(a,b,n)

"DIFSUMF ist eine Folge von Differnzen die aus Ober - u. Untersummen"

"zu einer vordefinierten Funktion F(x) erzeugt werden."

"a,b Intervallgrenzen, c Beginn der Zerlegungsfeinheit"

"d Ende der zerlegungsfeiheit, e Žnderung der Zerlegungsfeinheit"

DIFSUMF(a,b,c,d,e):=VECTOR(DIFSUM(a,b,r),r,c,d,e)

"URECT zeichnet ein unten liegendes Rechteck an der Stelle x"

"mit Breite dx zur Kurve"

URECT(x,dx):=[[x,0],[x+dx,0],[x+dx,F(x)],[x,F(x)],[x,0]]

"ORECT zeichnet ein oben liegendes Rechteck an der Stelle x"

"mit Breite dx zur Kurve"

ORECT(x,dx):=[[x,0],[x+dx,0],[x+dx,F(x+dx)],[x,F(x+dx)],[x,0]]

"URECTF zeichnet in [a,b] n unten liegende Rechtecke"

URECTF(a,b,n):=VECTOR(URECT(a+k*(b-a)/n,(b-a)/n),k,0,n-1)

"ORECTF zeichnet in [a,b] n oben liegende Rechtecke"

ORECTF(a,b,n):=VECTOR(ORECT(a+k*(b-a)/n,(b-a)/n),k,0,n-1)

"Streifen erzeugt ein Rechteck mit Breite dx um f(x) :"

STREIFEN(x,dx):=[[x+dx/2,0],[x+dx/2,F(x)],[x-dx/2,F(x)],[x-dx/2,0]]

STREIFENFLAECHE(x,dx):=F(x)*dx

FLAECHE(a,b,n):=SUM(STREIFENFLAECHE(a+(b-a)/(2*n)+i*(b-a)/n,(b-a)/n),i,0,n-1)

NSTREIFEN(a,b,n):=VECTOR(STREIFEN(i,(b-a)/n),i,a,b,(b-a)/n)